Question : FTP Batch FIle Needed

I need to create a batch file that will start FTP connect to a remote server and download a file. The challenge is that the file name is unique based on the day and date. For example, the file name for today might be 123456_Friday_08212009.xml. The following is what I have so far, I just can figure out how to tell FTP to download the unique file. Code is attached for the two files I have set up. The first is the batch file, the second is a text file that I am using to insert the FTP commands.

Any help will be much appreciated.

Code Snippet:

         
           
             1:
2:
3:
4:
5:
6:
7:
8:
9:
10:
11:
12:
13:
14:
15:
16:
17:
18:
19:
20:
21:

           
           
             BATCH FILE:
autobatch.bat
-----------------------------------
@ECHO OFF
ECHO DODGE LEAD DOWNLOAD MODULE
ECHO DOWNLOAD STEP 1 - CREATING LOG FILE...
ECHO %date% %time% RUNNING DOWNLOAD BATCH >> log.txt
 
ECHO %date% %time% RUNNING FTP BATCH >> logXML.txt
ECHO DOWNLOAD STEP 2 - DOWNLOADING FILES...
ftp -i -s:get-ftpXML.txt
ECHO ...................
-------------------------------------------------
get-ftpXML.txt
FTP COMMANDS TXT File
open ftpsite.com
lyXXXXX
lyXXXXX
hash
 
mget 589398758441399_Friday_08212009.xml

           
         

Open in New Window

Select All

Answer : FTP Batch FIle Needed

Before running this batch file.... modify the 'lyxxxx' and any other data in the 'MAKE FTP' section of the code.

NOTE: Shove a 'REM' infront of the "ftp -i -s:get-ftpXML.txt" command during testing so as to examine the "get-ftpXML.txt" file by typing "TYPE get-ftpXML.txt" in a DOS box.

If there are any problem, please report back.

:: ========================================
:: AUTOBATCH.BAT - Written by Paul Tomasi 2009
:: ========================================
:autobatch
@echo off
setlocal enabledelayedexpansion

echo.
echo DODGE LEAD DOWNLOAD MODULE
echo.
echo DOWNLOAD STEP 1 - CREATING LOG FILE...
echo %date% %time% RUNNING DOWNLOAD BATCH >> log.txt

call :get CurrentDate
call :convert CurrentDate to DateStamp
call :make ftp script file using DateStamp

echo.
echo DOWNLOAD STEP 2 - DOWNLOADING FILES...
echo %date% %time% RUNNING FTP BATCH >> logXML.txt

ftp -i -s:get-ftpXML.txt

echo.
echo ...................
exit /b 0

:: ----------------------------------------
:: GET [CurrentDate] - Written by Paul Tomasi 2009
:: ----------------------------------------
:get
for /f "tokens=3,3" %%a in ('reg query "hkcu\control panel\international" /v sshortdate') do (
set sfmt=%%a
)

reg add "hkcu\control panel\international" /v sshortdate /t reg_sz /d "ddd MMddyyyy" /f >nul
set %1=%date%
reg add "hkcu\control panel\international" /v sshortdate /t reg_sz /d "%sfmt%" /f >nul
goto :eof

:: ----------------------------------------
:: CONVERT [CurrentDate] to [DateStamp] - Written by Paul Tomasi 2009
:: ----------------------------------------
:convert
set %3=!%1:~-8!

for /f "tokens=1 delims=: " %%a in ('type "%~dpnx0" ^| findstr ":!%1:~0,3!"') do (
:Monday
:Tuesday
:Wednesday
:Thursday
:Friday
:Saturday
:Sunday
set %3=%%a_!%3!
)
goto :eof

:: ----------------------------------------
:: MAKE FTP script file using [DateStamp]
:: ----------------------------------------
:make
>get-ftpXML.txt echo open ftpsite.com
>>get-ftpXML.txt echo lyXXXXX
>>get-ftpXML.txt echo lyXXXXX
>>get-ftpXML.txt echo hash
>>get-ftpXML.txt echo mget 589398758441399_!%5!.xml
goto :eof